nmode's Git Repositories - signal-cli/blob - build.gradle.kts

   1 plugins {
   2     java
   3     application
   4     eclipse
   5     `check-lib-versions`
   6     id("org.graalvm.buildtools.native") version "0.10.6"
   7 }
   8
   9 allprojects {
  10     group = "org.asamk"
  11     version = "0.13.14"
  12 }
  13
  14 java {
  15     sourceCompatibility = JavaVersion.VERSION_21
  16     targetCompatibility = JavaVersion.VERSION_21
  17
  18     if (!JavaVersion.current().isCompatibleWith(targetCompatibility)) {
  19         toolchain {
  20             languageVersion.set(JavaLanguageVersion.of(targetCompatibility.majorVersion))
  21         }
  22     }
  23 }
  24
  25 application {
  26     mainClass.set("org.asamk.signal.Main")
  27 }
  28
  29 graalvmNative {
  30     binaries {
  31         this["main"].run {
  32             buildArgs.add("--install-exit-handlers")
  33             buildArgs.add("-Dfile.encoding=UTF-8")
  34             buildArgs.add("-J-Dfile.encoding=UTF-8")
  35             resources.autodetect()
  36             configurationFileDirectories.from(file("graalvm-config-dir"))
  37             if (System.getenv("GRAALVM_HOME") == null) {
  38                 toolchainDetection.set(true)
  39                 javaLauncher.set(javaToolchains.launcherFor {
  40                     languageVersion.set(JavaLanguageVersion.of(21))
  41                 })
  42             } else {
  43                 toolchainDetection.set(false)
  44             }
  45         }
  46     }
  47 }
  48
  49 val artifactType = Attribute.of("artifactType", String::class.java)
  50 val minified = Attribute.of("minified", Boolean::class.javaObjectType)
  51 dependencies {
  52     attributesSchema {
  53         attribute(minified)
  54     }
  55     artifactTypes.getByName("jar") {
  56         attributes.attribute(minified, false)
  57     }
  58 }
  59
  60 configurations.runtimeClasspath.configure {
  61     attributes {
  62         attribute(minified, true)
  63     }
  64 }
  65 val excludePatterns = mapOf(
  66     "libsignal-client" to setOf(
  67         "libsignal_jni_testing_amd64.so",
  68         "signal_jni_testing_amd64.dll",
  69         "libsignal_jni_testing_amd64.dylib",
  70         "libsignal_jni_testing_aarch64.dylib",
  71     )
  72 )
  73
  74 dependencies {
  75     registerTransform(JarFileExcluder::class) {
  76         from.attribute(minified, false).attribute(artifactType, "jar")
  77         to.attribute(minified, true).attribute(artifactType, "jar")
  78
  79         parameters {
  80             excludeFilesByArtifact = excludePatterns
  81         }
  82     }
  83
  84     implementation(libs.bouncycastle)
  85     implementation(libs.jackson.databind)
  86     implementation(libs.argparse4j)
  87     implementation(libs.dbusjava)
  88     implementation(libs.slf4j.api)
  89     implementation(libs.slf4j.jul)
  90     implementation(libs.logback)
  91     implementation(project(":libsignal-cli"))
  92 }
  93
  94 configurations {
  95     implementation {
  96         resolutionStrategy.failOnVersionConflict()
  97     }
  98 }
  99
 100
 101 tasks.withType<AbstractArchiveTask>().configureEach {
 102     isPreserveFileTimestamps = false
 103     isReproducibleFileOrder = true
 104 }
 105
 106 tasks.withType<JavaCompile> {
 107     options.encoding = "UTF-8"
 108 }
 109
 110 tasks.withType<Jar> {
 111     manifest {
 112         attributes(
 113             "Implementation-Title" to project.name,
 114             "Implementation-Version" to project.version,
 115             "Main-Class" to application.mainClass.get()
 116         )
 117     }
 118 }
 119
 120 tasks.register("fatJar", type = Jar::class) {
 121     archiveBaseName.set("${project.name}-fat")
 122     exclude(
 123         "META-INF/*.SF",
 124         "META-INF/*.DSA",
 125         "META-INF/*.RSA",
 126         "META-INF/NOTICE*",
 127         "META-INF/LICENSE*",
 128         "META-INF/INDEX.LIST",
 129         "**/module-info.class",
 130     )
 131     duplicatesStrategy = DuplicatesStrategy.WARN
 132     doFirst {
 133         from(configurations.runtimeClasspath.get().map { if (it.isDirectory) it else zipTree(it) })
 134     }
 135     with(tasks.jar.get())
 136 }