nmode's Git Repositories - signal-cli/blob - build.gradle

   1 apply plugin: 'java'
   2 apply plugin: 'application'
   3 apply plugin: 'eclipse'
   4
   5 sourceCompatibility = JavaVersion.VERSION_1_7
   6 targetCompatibility = JavaVersion.VERSION_1_7
   7
   8 mainClassName = 'org.asamk.signal.Main'
   9
  10 version = '0.6.0'
  11
  12 compileJava.options.encoding = 'UTF-8'
  13
  14 repositories {
  15     mavenLocal()
  16     maven {
  17         url "https://raw.github.com/AsamK/maven/master/releases/"
  18     }
  19     mavenCentral()
  20 }
  21
  22 dependencies {
  23     compile 'com.github.turasa:signal-service-java:2.9.0_unofficial_1'
  24     compile 'org.bouncycastle:bcprov-jdk15on:1.59'
  25     compile 'net.sourceforge.argparse4j:argparse4j:0.8.1'
  26     compile 'org.freedesktop.dbus:dbus-java:2.7.0'
  27 }
  28
  29 jar {
  30     manifest {
  31         attributes(
  32                 'Implementation-Title': project.name,
  33                 'Implementation-Version': project.version,
  34                 'Main-Class': project.mainClassName,
  35         )
  36     }
  37 }
  38
  39 run {
  40     if (project.hasProperty("appArgs")) {
  41         // allow passing command-line arguments to the main application e.g.:
  42         // $ gradle run -PappArgs="['-u', '+...', 'daemon', '--json']"
  43         args Eval.me(appArgs)
  44     }
  45 }
  46
  47 // Find any 3rd party libraries which have released new versions
  48 // to the central Maven repo since we last upgraded.
  49 // http://daniel.gredler.net/2011/08/08/gradle-keeping-libraries-up-to-date/
  50 task checkLibVersions << {
  51     def checked = [:]
  52     allprojects {
  53         configurations.each { configuration ->
  54             configuration.allDependencies.each { dependency ->
  55                 def version = dependency.version
  56                 if (!version.contains('SNAPSHOT') && !checked[dependency]) {
  57                     def group = dependency.group
  58                     def path = group.replace('.', '/')
  59                     def name = dependency.name
  60                     def url = "http://repo1.maven.org/maven2/$path/$name/maven-metadata.xml"
  61                     try {
  62                         def metadata = new XmlSlurper().parseText(url.toURL().text)
  63                         def versions = metadata.versioning.versions.version.collect { it.text() }
  64                         versions.removeAll { it.toLowerCase().contains('alpha') }
  65                         versions.removeAll { it.toLowerCase().contains('beta') }
  66                         versions.removeAll { it.toLowerCase().contains('rc') }
  67                         def newest = versions.max()
  68                         if (version != newest) {
  69                             println "$group:$name $version -> $newest"
  70                         }
  71                     } catch (FileNotFoundException e) {
  72                         logger.debug "Unable to download $url: $e.message"
  73                     } catch (org.xml.sax.SAXParseException e) {
  74                         logger.debug "Unable to parse $url: $e.message"
  75                     }
  76                     checked[dependency] = true
  77                 }
  78             }
  79         }
  80     }
  81 }