nmode's Git Repositories - signal-cli/blob - build.gradle.kts

   1 plugins {
   2     java
   3     application
   4     eclipse
   5     `check-lib-versions`
   6     id("org.graalvm.buildtools.native") version "0.10.2"
   7 }
   8
   9 version = "0.13.4-SNAPSHOT"
  10
  11 java {
  12     sourceCompatibility = JavaVersion.VERSION_21
  13     targetCompatibility = JavaVersion.VERSION_21
  14
  15     toolchain {
  16         languageVersion.set(JavaLanguageVersion.of(21))
  17     }
  18 }
  19
  20 application {
  21     mainClass.set("org.asamk.signal.Main")
  22 }
  23
  24 graalvmNative {
  25     binaries {
  26         this["main"].run {
  27             buildArgs.add("--install-exit-handlers")
  28             buildArgs.add("-Dfile.encoding=UTF-8")
  29             buildArgs.add("-J-Dfile.encoding=UTF-8")
  30             resources.autodetect()
  31             configurationFileDirectories.from(file("graalvm-config-dir"))
  32             if (System.getenv("GRAALVM_HOME") == null) {
  33                 toolchainDetection.set(true)
  34                 javaLauncher.set(javaToolchains.launcherFor {
  35                     languageVersion.set(JavaLanguageVersion.of(21))
  36                 })
  37             } else {
  38                 toolchainDetection.set(false)
  39             }
  40         }
  41     }
  42 }
  43
  44 dependencies {
  45     implementation(libs.bouncycastle)
  46     implementation(libs.jackson.databind)
  47     implementation(libs.argparse4j)
  48     implementation(libs.dbusjava)
  49     implementation(libs.slf4j.api)
  50     implementation(libs.slf4j.jul)
  51     implementation(libs.logback)
  52     implementation(project(":lib"))
  53 }
  54
  55 configurations {
  56     implementation {
  57         resolutionStrategy.failOnVersionConflict()
  58     }
  59 }
  60
  61
  62 tasks.withType<AbstractArchiveTask>().configureEach {
  63     isPreserveFileTimestamps = false
  64     isReproducibleFileOrder = true
  65 }
  66
  67 tasks.withType<JavaCompile> {
  68     options.encoding = "UTF-8"
  69 }
  70
  71 tasks.withType<Jar> {
  72     manifest {
  73         attributes(
  74             "Implementation-Title" to project.name,
  75             "Implementation-Version" to project.version,
  76             "Main-Class" to application.mainClass.get()
  77         )
  78     }
  79 }
  80
  81 task("fatJar", type = Jar::class) {
  82     archiveBaseName.set("${project.name}-fat")
  83     exclude(
  84         "META-INF/*.SF",
  85         "META-INF/*.DSA",
  86         "META-INF/*.RSA",
  87         "META-INF/NOTICE*",
  88         "META-INF/LICENSE*",
  89         "META-INF/INDEX.LIST",
  90         "**/module-info.class"
  91     )
  92     duplicatesStrategy = DuplicatesStrategy.WARN
  93     from(configurations.runtimeClasspath.get().map { if (it.isDirectory) it else zipTree(it) })
  94     with(tasks.jar.get())
  95 }