nmode's Git Repositories - signal-cli/blob - build.gradle.kts

   1 plugins {
   2     java
   3     application
   4     eclipse
   5     `check-lib-versions`
   6     id("org.graalvm.buildtools.native") version "0.9.9"
   7 }
   8
   9 version = "0.10.0"
  10
  11 java {
  12     sourceCompatibility = JavaVersion.VERSION_17
  13     targetCompatibility = JavaVersion.VERSION_17
  14 }
  15
  16 application {
  17     mainClass.set("org.asamk.signal.Main")
  18 }
  19
  20 graalvmNative {
  21     binaries {
  22         this["main"].run {
  23             configurationFileDirectories.from(file("graalvm-config-dir"))
  24             buildArgs.add("--allow-incomplete-classpath")
  25             buildArgs.add("--report-unsupported-elements-at-runtime")
  26         }
  27     }
  28 }
  29
  30 repositories {
  31     mavenLocal()
  32     mavenCentral()
  33 }
  34
  35 dependencies {
  36     implementation("org.bouncycastle", "bcprov-jdk15on", "1.70")
  37     implementation("com.fasterxml.jackson.core", "jackson-databind", "2.13.1")
  38     implementation("net.sourceforge.argparse4j", "argparse4j", "0.9.0")
  39     implementation("com.github.hypfvieh", "dbus-java-transport-native-unixsocket", "4.0.0")
  40     implementation("org.slf4j", "slf4j-simple", "1.7.32")
  41     implementation("org.slf4j", "jul-to-slf4j", "1.7.32")
  42     implementation(project(":lib"))
  43 }
  44
  45 configurations {
  46     implementation {
  47         resolutionStrategy.failOnVersionConflict()
  48     }
  49 }
  50
  51
  52 tasks.withType<AbstractArchiveTask>().configureEach {
  53     isPreserveFileTimestamps = false
  54     isReproducibleFileOrder = true
  55 }
  56
  57 tasks.withType<JavaCompile> {
  58     options.encoding = "UTF-8"
  59 }
  60
  61 tasks.withType<Jar> {
  62     manifest {
  63         attributes(
  64             "Implementation-Title" to project.name,
  65             "Implementation-Version" to project.version,
  66             "Main-Class" to application.mainClass.get()
  67         )
  68     }
  69 }
  70
  71 task("fatJar", type = Jar::class) {
  72     archiveBaseName.set("${project.name}-fat")
  73     exclude(
  74         "META-INF/*.SF",
  75         "META-INF/*.DSA",
  76         "META-INF/*.RSA",
  77         "META-INF/NOTICE",
  78         "META-INF/LICENSE",
  79         "**/module-info.class"
  80     )
  81     from(configurations.runtimeClasspath.get().map { if (it.isDirectory) it else zipTree(it) })
  82     with(tasks.jar.get() as CopySpec)
  83 }