nmode's Git Repositories - signal-cli/blob - build.gradle.kts

   1 plugins {
   2     java
   3     application
   4     eclipse
   5     `check-lib-versions`
   6     id("org.graalvm.buildtools.native") version "0.9.28"
   7 }
   8
   9 version = "0.12.5"
  10
  11 java {
  12     sourceCompatibility = JavaVersion.VERSION_17
  13     targetCompatibility = JavaVersion.VERSION_17
  14 }
  15
  16 application {
  17     mainClass.set("org.asamk.signal.Main")
  18 }
  19
  20 graalvmNative {
  21     binaries {
  22         this["main"].run {
  23             buildArgs.add("--install-exit-handlers")
  24             resources.autodetect()
  25             configurationFileDirectories.from(file("graalvm-config-dir"))
  26             if (System.getenv("GRAALVM_HOME") == null) {
  27                 toolchainDetection.set(true)
  28                 javaLauncher.set(javaToolchains.launcherFor {
  29                     languageVersion.set(JavaLanguageVersion.of(17))
  30                 })
  31             } else {
  32                 toolchainDetection.set(false)
  33             }
  34         }
  35     }
  36 }
  37
  38 dependencies {
  39     implementation(libs.bouncycastle)
  40     implementation(libs.jackson.databind)
  41     implementation(libs.argparse4j)
  42     implementation(libs.dbusjava)
  43     implementation(libs.slf4j.api)
  44     implementation(libs.slf4j.jul)
  45     implementation(libs.logback)
  46     implementation(project(":lib"))
  47 }
  48
  49 configurations {
  50     implementation {
  51         resolutionStrategy.failOnVersionConflict()
  52     }
  53 }
  54
  55
  56 tasks.withType<AbstractArchiveTask>().configureEach {
  57     isPreserveFileTimestamps = false
  58     isReproducibleFileOrder = true
  59 }
  60
  61 tasks.withType<JavaCompile> {
  62     options.encoding = "UTF-8"
  63 }
  64
  65 tasks.withType<Jar> {
  66     manifest {
  67         attributes(
  68             "Implementation-Title" to project.name,
  69             "Implementation-Version" to project.version,
  70             "Main-Class" to application.mainClass.get()
  71         )
  72     }
  73 }
  74
  75 task("fatJar", type = Jar::class) {
  76     archiveBaseName.set("${project.name}-fat")
  77     exclude(
  78         "META-INF/*.SF",
  79         "META-INF/*.DSA",
  80         "META-INF/*.RSA",
  81         "META-INF/NOTICE*",
  82         "META-INF/LICENSE*",
  83         "META-INF/INDEX.LIST",
  84         "**/module-info.class"
  85     )
  86     duplicatesStrategy = DuplicatesStrategy.WARN
  87     from(configurations.runtimeClasspath.get().map { if (it.isDirectory) it else zipTree(it) })
  88     with(tasks.jar.get())
  89 }