nmode's Git Repositories - signal-cli/blob - build.gradle.kts

   1 plugins {
   2     java
   3     application
   4     eclipse
   5     `check-lib-versions`
   6     id("org.graalvm.buildtools.native") version "0.9.28"
   7 }
   8
   9 version = "0.12.4"
  10
  11 java {
  12     sourceCompatibility = JavaVersion.VERSION_21
  13     targetCompatibility = JavaVersion.VERSION_21
  14
  15     toolchain {
  16         languageVersion.set(JavaLanguageVersion.of(21))
  17     }
  18 }
  19
  20 application {
  21     mainClass.set("org.asamk.signal.Main")
  22 }
  23
  24 graalvmNative {
  25     binaries {
  26         this["main"].run {
  27             buildArgs.add("--install-exit-handlers")
  28             resources.autodetect()
  29             configurationFileDirectories.from(file("graalvm-config-dir"))
  30             if (System.getenv("GRAALVM_HOME") == null) {
  31                 toolchainDetection.set(true)
  32                 javaLauncher.set(javaToolchains.launcherFor {
  33                     languageVersion.set(JavaLanguageVersion.of(21))
  34                 })
  35             } else {
  36                 toolchainDetection.set(false)
  37             }
  38         }
  39     }
  40 }
  41
  42 dependencies {
  43     implementation(libs.bouncycastle)
  44     implementation(libs.jackson.databind)
  45     implementation(libs.argparse4j)
  46     implementation(libs.dbusjava)
  47     implementation(libs.slf4j.api)
  48     implementation(libs.slf4j.jul)
  49     implementation(libs.logback)
  50     implementation(project(":lib"))
  51 }
  52
  53 configurations {
  54     implementation {
  55         resolutionStrategy.failOnVersionConflict()
  56     }
  57 }
  58
  59
  60 tasks.withType<AbstractArchiveTask>().configureEach {
  61     isPreserveFileTimestamps = false
  62     isReproducibleFileOrder = true
  63 }
  64
  65 tasks.withType<JavaCompile> {
  66     options.encoding = "UTF-8"
  67 }
  68
  69 tasks.withType<Jar> {
  70     manifest {
  71         attributes(
  72             "Implementation-Title" to project.name,
  73             "Implementation-Version" to project.version,
  74             "Main-Class" to application.mainClass.get()
  75         )
  76     }
  77 }
  78
  79 task("fatJar", type = Jar::class) {
  80     archiveBaseName.set("${project.name}-fat")
  81     exclude(
  82         "META-INF/*.SF",
  83         "META-INF/*.DSA",
  84         "META-INF/*.RSA",
  85         "META-INF/NOTICE*",
  86         "META-INF/LICENSE*",
  87         "META-INF/INDEX.LIST",
  88         "**/module-info.class"
  89     )
  90     duplicatesStrategy = DuplicatesStrategy.WARN
  91     from(configurations.runtimeClasspath.get().map { if (it.isDirectory) it else zipTree(it) })
  92     with(tasks.jar.get())
  93 }