nmode's Git Repositories - signal-cli/blob - lib/build.gradle.kts

   1 plugins {
   2     `java-library`
   3     `check-lib-versions`
   4 }
   5
   6 java {
   7     sourceCompatibility = JavaVersion.VERSION_17
   8     targetCompatibility = JavaVersion.VERSION_17
   9 }
  10
  11 val libsignalClientPath = project.findProperty("libsignal_client_path")?.toString()
  12
  13 dependencies {
  14     if (libsignalClientPath == null) {
  15         implementation(libs.signalservice)
  16     } else {
  17         implementation(libs.signalservice) {
  18             exclude(group = "org.signal", module = "libsignal-client")
  19         }
  20         implementation(files(libsignalClientPath))
  21     }
  22     implementation(libs.jackson.databind)
  23     implementation(libs.bouncycastle)
  24     implementation(libs.slf4j.api)
  25     implementation(libs.sqlite)
  26     implementation(libs.hikari)
  27
  28     testImplementation(libs.junit.jupiter)
  29     testRuntimeOnly(libs.junit.launcher)
  30 }
  31
  32 tasks.named<Test>("test") {
  33     useJUnitPlatform()
  34 }
  35
  36 configurations {
  37     implementation {
  38         resolutionStrategy.failOnVersionConflict()
  39     }
  40 }
  41
  42 tasks.withType<AbstractArchiveTask>().configureEach {
  43     isPreserveFileTimestamps = false
  44     isReproducibleFileOrder = true
  45 }
  46
  47 tasks.withType<JavaCompile> {
  48     options.encoding = "UTF-8"
  49 }
  50
  51 tasks.jar {
  52     manifest {
  53         attributes("Automatic-Module-Name" to "org.asamk.signal.manager")
  54     }
  55 }