nmode's Git Repositories - signal-cli/blob - build.gradle.kts

   1 plugins {
   2     java
   3     application
   4     eclipse
   5     `check-lib-versions`
   6     id("org.graalvm.buildtools.native") version "0.10.5"
   7 }
   8
   9 allprojects {
  10     group = "org.asamk"
  11     version = "0.13.13-SNAPSHOT"
  12 }
  13
  14 java {
  15     sourceCompatibility = JavaVersion.VERSION_21
  16     targetCompatibility = JavaVersion.VERSION_21
  17
  18     if (!JavaVersion.current().isCompatibleWith(targetCompatibility)) {
  19         toolchain {
  20             languageVersion.set(JavaLanguageVersion.of(targetCompatibility.majorVersion))
  21         }
  22     }
  23 }
  24
  25 application {
  26     mainClass.set("org.asamk.signal.Main")
  27 }
  28
  29 graalvmNative {
  30     binaries {
  31         this["main"].run {
  32             buildArgs.add("--install-exit-handlers")
  33             buildArgs.add("-Dfile.encoding=UTF-8")
  34             buildArgs.add("-J-Dfile.encoding=UTF-8")
  35             resources.autodetect()
  36             configurationFileDirectories.from(file("graalvm-config-dir"))
  37             if (System.getenv("GRAALVM_HOME") == null) {
  38                 toolchainDetection.set(true)
  39                 javaLauncher.set(javaToolchains.launcherFor {
  40                     languageVersion.set(JavaLanguageVersion.of(21))
  41                 })
  42             } else {
  43                 toolchainDetection.set(false)
  44             }
  45         }
  46     }
  47 }
  48
  49 dependencies {
  50     implementation(libs.bouncycastle)
  51     implementation(libs.jackson.databind)
  52     implementation(libs.argparse4j)
  53     implementation(libs.dbusjava)
  54     implementation(libs.slf4j.api)
  55     implementation(libs.slf4j.jul)
  56     implementation(libs.logback)
  57     implementation(project(":libsignal-cli"))
  58 }
  59
  60 configurations {
  61     implementation {
  62         resolutionStrategy.failOnVersionConflict()
  63     }
  64 }
  65
  66
  67 tasks.withType<AbstractArchiveTask>().configureEach {
  68     isPreserveFileTimestamps = false
  69     isReproducibleFileOrder = true
  70 }
  71
  72 tasks.withType<JavaCompile> {
  73     options.encoding = "UTF-8"
  74 }
  75
  76 tasks.withType<Jar> {
  77     manifest {
  78         attributes(
  79             "Implementation-Title" to project.name,
  80             "Implementation-Version" to project.version,
  81             "Main-Class" to application.mainClass.get()
  82         )
  83     }
  84 }
  85
  86 task("fatJar", type = Jar::class) {
  87     archiveBaseName.set("${project.name}-fat")
  88     exclude(
  89         "META-INF/*.SF",
  90         "META-INF/*.DSA",
  91         "META-INF/*.RSA",
  92         "META-INF/NOTICE*",
  93         "META-INF/LICENSE*",
  94         "META-INF/INDEX.LIST",
  95         "**/module-info.class"
  96     )
  97     duplicatesStrategy = DuplicatesStrategy.WARN
  98     from(configurations.runtimeClasspath.get().map { if (it.isDirectory) it else zipTree(it) })
  99     with(tasks.jar.get())
 100 }