nmode's Git Repositories - signal-cli/blob - build.gradle.kts

   1 plugins {
   2     java
   3     application
   4     eclipse
   5     `check-lib-versions`
   6     id("org.graalvm.buildtools.native") version "0.9.20"
   7 }
   8
   9 version = "0.11.6"
  10
  11 java {
  12     sourceCompatibility = JavaVersion.VERSION_17
  13     targetCompatibility = JavaVersion.VERSION_17
  14 }
  15
  16 application {
  17     mainClass.set("org.asamk.signal.Main")
  18 }
  19
  20 graalvmNative {
  21     binaries {
  22         this["main"].run {
  23             resources.autodetect()
  24             configurationFileDirectories.from(file("graalvm-config-dir"))
  25             if (System.getenv("GRAALVM_HOME") == null) {
  26                 javaLauncher.set(javaToolchains.launcherFor {
  27                     languageVersion.set(JavaLanguageVersion.of(17))
  28                 })
  29             } else {
  30                 toolchainDetection.set(false)
  31             }
  32         }
  33     }
  34 }
  35
  36 dependencies {
  37     implementation(libs.bouncycastle)
  38     implementation(libs.jackson.databind)
  39     implementation(libs.argparse4j)
  40     implementation(libs.dbusjava)
  41     implementation(libs.slf4j.api)
  42     implementation(libs.slf4j.jul)
  43     implementation(libs.logback)
  44     implementation(project(":lib"))
  45 }
  46
  47 configurations {
  48     implementation {
  49         resolutionStrategy.failOnVersionConflict()
  50     }
  51 }
  52
  53
  54 tasks.withType<AbstractArchiveTask>().configureEach {
  55     isPreserveFileTimestamps = false
  56     isReproducibleFileOrder = true
  57 }
  58
  59 tasks.withType<JavaCompile> {
  60     options.encoding = "UTF-8"
  61 }
  62
  63 tasks.withType<Jar> {
  64     manifest {
  65         attributes(
  66             "Implementation-Title" to project.name,
  67             "Implementation-Version" to project.version,
  68             "Main-Class" to application.mainClass.get()
  69         )
  70     }
  71 }
  72
  73 task("fatJar", type = Jar::class) {
  74     archiveBaseName.set("${project.name}-fat")
  75     exclude(
  76         "META-INF/*.SF",
  77         "META-INF/*.DSA",
  78         "META-INF/*.RSA",
  79         "META-INF/NOTICE*",
  80         "META-INF/LICENSE*",
  81         "META-INF/INDEX.LIST",
  82         "**/module-info.class"
  83     )
  84     duplicatesStrategy = DuplicatesStrategy.WARN
  85     from(configurations.runtimeClasspath.get().map { if (it.isDirectory) it else zipTree(it) })
  86     with(tasks.jar.get())
  87 }