nmode's Git Repositories - signal-cli/blob - build.gradle.kts

   1 plugins {
   2     java
   3     application
   4     eclipse
   5     `check-lib-versions`
   6     id("org.graalvm.buildtools.native") version "0.9.28"
   7 }
   8
   9 version = "0.12.4"
  10
  11 java {
  12     sourceCompatibility = JavaVersion.VERSION_17
  13     targetCompatibility = JavaVersion.VERSION_17
  14 }
  15
  16 application {
  17     mainClass.set("org.asamk.signal.Main")
  18 }
  19
  20 graalvmNative {
  21     binaries {
  22         this["main"].run {
  23             resources.autodetect()
  24             configurationFileDirectories.from(file("graalvm-config-dir"))
  25             if (System.getenv("GRAALVM_HOME") == null) {
  26                 toolchainDetection.set(true)
  27                 javaLauncher.set(javaToolchains.launcherFor {
  28                     languageVersion.set(JavaLanguageVersion.of(17))
  29                 })
  30             } else {
  31                 toolchainDetection.set(false)
  32             }
  33         }
  34     }
  35 }
  36
  37 dependencies {
  38     implementation(libs.bouncycastle)
  39     implementation(libs.jackson.databind)
  40     implementation(libs.argparse4j)
  41     implementation(libs.dbusjava)
  42     implementation(libs.slf4j.api)
  43     implementation(libs.slf4j.jul)
  44     implementation(libs.logback)
  45     implementation(project(":lib"))
  46 }
  47
  48 configurations {
  49     implementation {
  50         resolutionStrategy.failOnVersionConflict()
  51     }
  52 }
  53
  54
  55 tasks.withType<AbstractArchiveTask>().configureEach {
  56     isPreserveFileTimestamps = false
  57     isReproducibleFileOrder = true
  58 }
  59
  60 tasks.withType<JavaCompile> {
  61     options.encoding = "UTF-8"
  62 }
  63
  64 tasks.withType<Jar> {
  65     manifest {
  66         attributes(
  67             "Implementation-Title" to project.name,
  68             "Implementation-Version" to project.version,
  69             "Main-Class" to application.mainClass.get()
  70         )
  71     }
  72 }
  73
  74 task("fatJar", type = Jar::class) {
  75     archiveBaseName.set("${project.name}-fat")
  76     exclude(
  77         "META-INF/*.SF",
  78         "META-INF/*.DSA",
  79         "META-INF/*.RSA",
  80         "META-INF/NOTICE*",
  81         "META-INF/LICENSE*",
  82         "META-INF/INDEX.LIST",
  83         "**/module-info.class"
  84     )
  85     duplicatesStrategy = DuplicatesStrategy.WARN
  86     from(configurations.runtimeClasspath.get().map { if (it.isDirectory) it else zipTree(it) })
  87     with(tasks.jar.get())
  88 }