nmode's Git Repositories - signal-cli/blob - build.gradle.kts

   1 plugins {
   2     java
   3     application
   4     eclipse
   5     `check-lib-versions`
   6     id("org.graalvm.buildtools.native") version "0.9.28"
   7 }
   8
   9 version = "0.12.4"
  10
  11 java {
  12     sourceCompatibility = JavaVersion.VERSION_21
  13     targetCompatibility = JavaVersion.VERSION_21
  14
  15     toolchain {
  16         languageVersion.set(JavaLanguageVersion.of(21))
  17     }
  18 }
  19
  20 application {
  21     mainClass.set("org.asamk.signal.Main")
  22 }
  23
  24 graalvmNative {
  25     binaries {
  26         this["main"].run {
  27             resources.autodetect()
  28             configurationFileDirectories.from(file("graalvm-config-dir"))
  29             if (System.getenv("GRAALVM_HOME") == null) {
  30                 toolchainDetection.set(true)
  31                 javaLauncher.set(javaToolchains.launcherFor {
  32                     languageVersion.set(JavaLanguageVersion.of(21))
  33                 })
  34             } else {
  35                 toolchainDetection.set(false)
  36             }
  37         }
  38     }
  39 }
  40
  41 dependencies {
  42     implementation(libs.bouncycastle)
  43     implementation(libs.jackson.databind)
  44     implementation(libs.argparse4j)
  45     implementation(libs.dbusjava)
  46     implementation(libs.slf4j.api)
  47     implementation(libs.slf4j.jul)
  48     implementation(libs.logback)
  49     implementation(project(":lib"))
  50 }
  51
  52 configurations {
  53     implementation {
  54         resolutionStrategy.failOnVersionConflict()
  55     }
  56 }
  57
  58
  59 tasks.withType<AbstractArchiveTask>().configureEach {
  60     isPreserveFileTimestamps = false
  61     isReproducibleFileOrder = true
  62 }
  63
  64 tasks.withType<JavaCompile> {
  65     options.encoding = "UTF-8"
  66 }
  67
  68 tasks.withType<Jar> {
  69     manifest {
  70         attributes(
  71             "Implementation-Title" to project.name,
  72             "Implementation-Version" to project.version,
  73             "Main-Class" to application.mainClass.get()
  74         )
  75     }
  76 }
  77
  78 task("fatJar", type = Jar::class) {
  79     archiveBaseName.set("${project.name}-fat")
  80     exclude(
  81         "META-INF/*.SF",
  82         "META-INF/*.DSA",
  83         "META-INF/*.RSA",
  84         "META-INF/NOTICE*",
  85         "META-INF/LICENSE*",
  86         "META-INF/INDEX.LIST",
  87         "**/module-info.class"
  88     )
  89     duplicatesStrategy = DuplicatesStrategy.WARN
  90     from(configurations.runtimeClasspath.get().map { if (it.isDirectory) it else zipTree(it) })
  91     with(tasks.jar.get())
  92 }