nmode's Git Repositories - signal-cli/blob - build.gradle.kts

   1 plugins {
   2     java
   3     application
   4     eclipse
   5     `check-lib-versions`
   6     id("org.graalvm.buildtools.native") version "0.10.6"
   7 }
   8
   9 allprojects {
  10     group = "org.asamk"
  11     version = "0.13.16-SNAPSHOT"
  12 }
  13
  14 java {
  15     sourceCompatibility = JavaVersion.VERSION_21
  16     targetCompatibility = JavaVersion.VERSION_21
  17
  18     if (!JavaVersion.current().isCompatibleWith(targetCompatibility)) {
  19         toolchain {
  20             languageVersion.set(JavaLanguageVersion.of(targetCompatibility.majorVersion))
  21         }
  22     }
  23 }
  24
  25 application {
  26     mainClass.set("org.asamk.signal.Main")
  27     applicationDefaultJvmArgs = listOf("--enable-native-access=ALL-UNNAMED")
  28 }
  29
  30 graalvmNative {
  31     binaries {
  32         this["main"].run {
  33             buildArgs.add("--install-exit-handlers")
  34             buildArgs.add("-Dfile.encoding=UTF-8")
  35             buildArgs.add("-J-Dfile.encoding=UTF-8")
  36             buildArgs.add("-march=compatibility")
  37             resources.autodetect()
  38             configurationFileDirectories.from(file("graalvm-config-dir"))
  39             if (System.getenv("GRAALVM_HOME") == null) {
  40                 toolchainDetection.set(true)
  41                 javaLauncher.set(javaToolchains.launcherFor {
  42                     languageVersion.set(JavaLanguageVersion.of(21))
  43                 })
  44             } else {
  45                 toolchainDetection.set(false)
  46             }
  47         }
  48     }
  49 }
  50
  51 val artifactType = Attribute.of("artifactType", String::class.java)
  52 val minified = Attribute.of("minified", Boolean::class.javaObjectType)
  53 dependencies {
  54     attributesSchema {
  55         attribute(minified)
  56     }
  57     artifactTypes.getByName("jar") {
  58         attributes.attribute(minified, false)
  59     }
  60 }
  61
  62 configurations.runtimeClasspath.configure {
  63     attributes {
  64         attribute(minified, true)
  65     }
  66 }
  67 val excludePatterns = mapOf(
  68     "libsignal-client" to setOf(
  69         "libsignal_jni_testing_amd64.so",
  70         "signal_jni_testing_amd64.dll",
  71         "libsignal_jni_testing_amd64.dylib",
  72         "libsignal_jni_testing_aarch64.dylib",
  73     )
  74 )
  75
  76 dependencies {
  77     registerTransform(JarFileExcluder::class) {
  78         from.attribute(minified, false).attribute(artifactType, "jar")
  79         to.attribute(minified, true).attribute(artifactType, "jar")
  80
  81         parameters {
  82             excludeFilesByArtifact = excludePatterns
  83         }
  84     }
  85
  86     implementation(libs.bouncycastle)
  87     implementation(libs.jackson.databind)
  88     implementation(libs.argparse4j)
  89     implementation(libs.dbusjava)
  90     implementation(libs.slf4j.api)
  91     implementation(libs.slf4j.jul)
  92     implementation(libs.logback)
  93     implementation(project(":libsignal-cli"))
  94 }
  95
  96 configurations {
  97     implementation {
  98         resolutionStrategy.failOnVersionConflict()
  99     }
 100 }
 101
 102
 103 tasks.withType<AbstractArchiveTask>().configureEach {
 104     isPreserveFileTimestamps = false
 105     isReproducibleFileOrder = true
 106 }
 107
 108 tasks.withType<JavaCompile> {
 109     options.encoding = "UTF-8"
 110 }
 111
 112 tasks.withType<Jar> {
 113     manifest {
 114         attributes(
 115             "Implementation-Title" to project.name,
 116             "Implementation-Version" to project.version,
 117             "Main-Class" to application.mainClass.get(),
 118             "Enable-Native-Access" to "ALL-UNNAMED",
 119         )
 120     }
 121 }
 122
 123 tasks.register("fatJar", type = Jar::class) {
 124     archiveBaseName.set("${project.name}-fat")
 125     exclude(
 126         "META-INF/*.SF",
 127         "META-INF/*.DSA",
 128         "META-INF/*.RSA",
 129         "META-INF/NOTICE*",
 130         "META-INF/LICENSE*",
 131         "META-INF/INDEX.LIST",
 132         "**/module-info.class",
 133     )
 134     duplicatesStrategy = DuplicatesStrategy.WARN
 135     doFirst {
 136         from(configurations.runtimeClasspath.get().map { if (it.isDirectory) it else zipTree(it) })
 137     }
 138     with(tasks.jar.get())
 139 }