nmode's Git Repositories - signal-cli/blob - lib/build.gradle.kts

   1 plugins {
   2     `java-library`
   3     `check-lib-versions`
   4 }
   5
   6 java {
   7     sourceCompatibility = JavaVersion.VERSION_21
   8     targetCompatibility = JavaVersion.VERSION_21
   9
  10     toolchain {
  11         languageVersion.set(JavaLanguageVersion.of(21))
  12     }
  13 }
  14
  15 val libsignalClientPath = project.findProperty("libsignal_client_path")?.toString()
  16
  17 dependencies {
  18     if (libsignalClientPath == null) {
  19         implementation(libs.signalservice)
  20     } else {
  21         implementation(libs.signalservice) {
  22             exclude(group = "org.signal", module = "libsignal-client")
  23         }
  24         implementation(files(libsignalClientPath))
  25     }
  26     implementation(libs.jackson.databind)
  27     implementation(libs.bouncycastle)
  28     implementation(libs.slf4j.api)
  29     implementation(libs.sqlite)
  30     implementation(libs.hikari)
  31
  32     testImplementation(libs.junit)
  33 }
  34
  35 tasks.named<Test>("test") {
  36     useJUnitPlatform()
  37 }
  38
  39 configurations {
  40     implementation {
  41         resolutionStrategy.failOnVersionConflict()
  42     }
  43 }
  44
  45 tasks.withType<AbstractArchiveTask>().configureEach {
  46     isPreserveFileTimestamps = false
  47     isReproducibleFileOrder = true
  48 }
  49
  50 tasks.withType<JavaCompile> {
  51     options.encoding = "UTF-8"
  52 }
  53
  54 tasks.jar {
  55     manifest {
  56         attributes("Automatic-Module-Name" to "org.asamk.signal.manager")
  57     }
  58 }