nmode's Git Repositories - signal-cli/blob - build.gradle

   1 plugins {
   2     id "java"
   3     id "application"
   4     id "eclipse"
   5 }
   6
   7 sourceCompatibility = JavaVersion.VERSION_11
   8 targetCompatibility = JavaVersion.VERSION_11
   9
  10 mainClassName = "org.asamk.signal.Main"
  11
  12 version = "0.7.4"
  13
  14 compileJava.options.encoding = "UTF-8"
  15
  16 repositories {
  17     mavenLocal()
  18     mavenCentral()
  19 }
  20
  21 dependencies {
  22     implementation("com.google.protobuf:protobuf-javalite:3.10.0")
  23     implementation("com.github.turasa:signal-service-java:2.15.3_unofficial_18")
  24     implementation("org.bouncycastle:bcprov-jdk15on:1.68")
  25     implementation("net.sourceforge.argparse4j:argparse4j:0.8.1")
  26     implementation("com.github.hypfvieh:dbus-java:3.2.4")
  27     implementation("org.slf4j:slf4j-simple:1.7.30")
  28 }
  29
  30 jar {
  31     manifest {
  32         attributes(
  33                 "Implementation-Title": project.name,
  34                 "Implementation-Version": project.version,
  35                 "Main-Class": project.mainClassName,
  36         )
  37     }
  38 }
  39
  40 run {
  41     if (project.hasProperty("appArgs")) {
  42         // allow passing command-line arguments to the main application e.g.:
  43         // $ gradle run -PappArgs="['-u', '+...', 'daemon', '--json']"
  44         args(Eval.me(appArgs))
  45     }
  46 }
  47
  48 // Find any 3rd party libraries which have released new versions
  49 // to the central Maven repo since we last upgraded.
  50 task checkLibVersions {
  51     doLast {
  52         def checked = [:]
  53         allprojects {
  54             configurations.each { configuration ->
  55                 configuration.allDependencies.each { dependency ->
  56                     def version = dependency.version
  57                     if (!checked[dependency]) {
  58                         def group = dependency.group
  59                         def path = group.replace(".", "/")
  60                         def name = dependency.name
  61                         def url = "https://repo1.maven.org/maven2/$path/$name/maven-metadata.xml"
  62                         try {
  63                             def metadata = new XmlSlurper().parseText(url.toURL().text)
  64                             def newest = metadata.versioning.latest;
  65                             if ("$version" != "$newest") {
  66                                 println("UPGRADE {\"group\": \"$group\", \"name\": \"$name\", \"current\": \"$version\", \"latest\": \"$newest\"}")
  67                             }
  68                         } catch (FileNotFoundException e) {
  69                             logger.debug("Unable to download $url: $e.message")
  70                         } catch (org.xml.sax.SAXParseException e) {
  71                             logger.debug("Unable to parse $url: $e.message")
  72                         }
  73                         checked[dependency] = true
  74                     }
  75                 }
  76             }
  77         }
  78     }
  79 }
  80
  81 task assembleNativeImage {
  82     dependsOn("assemble")
  83     doLast {
  84         def graalVMHome = System.getenv("GRAALVM_HOME")
  85         if (!graalVMHome) {
  86             throw new GradleException("Required GRAALVM_HOME environment variable not set.")
  87         }
  88         def nativeBinaryOutputPath = "$buildDir/native-image"
  89         def nativeBinaryName = "signal-cli"
  90
  91         mkdir(nativeBinaryOutputPath)
  92
  93         exec {
  94             workingDir = "."
  95             commandLine("$graalVMHome/bin/native-image",
  96                     "-H:Path=$nativeBinaryOutputPath",
  97                     "-H:Name=$nativeBinaryName",
  98                     "-H:JNIConfigurationFiles=graalvm-config-dir/jni-config.json",
  99                     "-H:DynamicProxyConfigurationFiles=graalvm-config-dir/proxy-config.json",
 100                     "-H:ResourceConfigurationFiles=graalvm-config-dir/resource-config.json",
 101                     "-H:ReflectionConfigurationFiles=graalvm-config-dir/reflect-config.json",
 102                     "--no-fallback",
 103                     "--allow-incomplete-classpath",
 104                     "--report-unsupported-elements-at-runtime",
 105                     "--enable-url-protocols=http,https",
 106                     "--enable-https",
 107                     "--enable-all-security-services",
 108                     "-cp",
 109                     sourceSets.main.runtimeClasspath.asPath,
 110                     project.mainClassName)
 111         }
 112     }
 113 }