nmode's Git Repositories - signal-cli/blob - build.gradle.kts

   1 plugins {
   2     java
   3     application
   4     eclipse
   5     `check-lib-versions`
   6     id("org.graalvm.buildtools.native") version "0.9.16"
   7 }
   8
   9 version = "0.11.4"
  10
  11 java {
  12     sourceCompatibility = JavaVersion.VERSION_17
  13     targetCompatibility = JavaVersion.VERSION_17
  14 }
  15
  16 application {
  17     mainClass.set("org.asamk.signal.Main")
  18 }
  19
  20 graalvmNative {
  21     binaries {
  22         this["main"].run {
  23             resources.autodetect()
  24             configurationFileDirectories.from(file("graalvm-config-dir"))
  25             if (System.getenv("GRAALVM_HOME") == null) {
  26                 javaLauncher.set(javaToolchains.launcherFor {
  27                     languageVersion.set(JavaLanguageVersion.of(17))
  28                 })
  29             } else {
  30                 toolchainDetection.set(false)
  31             }
  32         }
  33     }
  34 }
  35
  36 repositories {
  37     mavenLocal()
  38     mavenCentral()
  39 }
  40
  41 dependencies {
  42     implementation("org.bouncycastle", "bcprov-jdk15on", "1.70")
  43     implementation("com.fasterxml.jackson.core", "jackson-databind", "2.13.4.2")
  44     implementation("net.sourceforge.argparse4j", "argparse4j", "0.9.0")
  45     implementation("com.github.hypfvieh", "dbus-java-transport-native-unixsocket", "4.2.1")
  46     implementation("org.slf4j", "slf4j-api", "2.0.3")
  47     implementation("ch.qos.logback", "logback-classic", "1.4.4")
  48     implementation("org.slf4j", "jul-to-slf4j", "2.0.3")
  49     implementation(project(":lib"))
  50 }
  51
  52 configurations {
  53     implementation {
  54         resolutionStrategy.failOnVersionConflict()
  55     }
  56 }
  57
  58
  59 tasks.withType<AbstractArchiveTask>().configureEach {
  60     isPreserveFileTimestamps = false
  61     isReproducibleFileOrder = true
  62 }
  63
  64 tasks.withType<JavaCompile> {
  65     options.encoding = "UTF-8"
  66 }
  67
  68 tasks.withType<Jar> {
  69     manifest {
  70         attributes(
  71             "Implementation-Title" to project.name,
  72             "Implementation-Version" to project.version,
  73             "Main-Class" to application.mainClass.get()
  74         )
  75     }
  76 }
  77
  78 task("fatJar", type = Jar::class) {
  79     archiveBaseName.set("${project.name}-fat")
  80     exclude(
  81         "META-INF/*.SF",
  82         "META-INF/*.DSA",
  83         "META-INF/*.RSA",
  84         "META-INF/NOTICE*",
  85         "META-INF/LICENSE*",
  86         "META-INF/INDEX.LIST",
  87         "**/module-info.class"
  88     )
  89     duplicatesStrategy = DuplicatesStrategy.WARN
  90     from(configurations.runtimeClasspath.get().map { if (it.isDirectory) it else zipTree(it) })
  91     with(tasks.jar.get())
  92 }