nmode's Git Repositories - signal-cli/blob - build.gradle.kts

   1 plugins {
   2     java
   3     application
   4     eclipse
   5     `check-lib-versions`
   6     id("org.graalvm.buildtools.native") version "0.10.6"
   7 }
   8
   9 allprojects {
  10     group = "org.asamk"
  11     version = "0.13.15-SNAPSHOT"
  12 }
  13
  14 java {
  15     sourceCompatibility = JavaVersion.VERSION_21
  16     targetCompatibility = JavaVersion.VERSION_21
  17
  18     if (!JavaVersion.current().isCompatibleWith(targetCompatibility)) {
  19         toolchain {
  20             languageVersion.set(JavaLanguageVersion.of(targetCompatibility.majorVersion))
  21         }
  22     }
  23 }
  24
  25 application {
  26     mainClass.set("org.asamk.signal.Main")
  27     applicationDefaultJvmArgs = listOf("--enable-native-access=ALL-UNNAMED")
  28 }
  29
  30 graalvmNative {
  31     binaries {
  32         this["main"].run {
  33             buildArgs.add("--install-exit-handlers")
  34             buildArgs.add("-Dfile.encoding=UTF-8")
  35             buildArgs.add("-J-Dfile.encoding=UTF-8")
  36             resources.autodetect()
  37             configurationFileDirectories.from(file("graalvm-config-dir"))
  38             if (System.getenv("GRAALVM_HOME") == null) {
  39                 toolchainDetection.set(true)
  40                 javaLauncher.set(javaToolchains.launcherFor {
  41                     languageVersion.set(JavaLanguageVersion.of(21))
  42                 })
  43             } else {
  44                 toolchainDetection.set(false)
  45             }
  46         }
  47     }
  48 }
  49
  50 val artifactType = Attribute.of("artifactType", String::class.java)
  51 val minified = Attribute.of("minified", Boolean::class.javaObjectType)
  52 dependencies {
  53     attributesSchema {
  54         attribute(minified)
  55     }
  56     artifactTypes.getByName("jar") {
  57         attributes.attribute(minified, false)
  58     }
  59 }
  60
  61 configurations.runtimeClasspath.configure {
  62     attributes {
  63         attribute(minified, true)
  64     }
  65 }
  66 val excludePatterns = mapOf(
  67     "libsignal-client" to setOf(
  68         "libsignal_jni_testing_amd64.so",
  69         "signal_jni_testing_amd64.dll",
  70         "libsignal_jni_testing_amd64.dylib",
  71         "libsignal_jni_testing_aarch64.dylib",
  72     )
  73 )
  74
  75 dependencies {
  76     registerTransform(JarFileExcluder::class) {
  77         from.attribute(minified, false).attribute(artifactType, "jar")
  78         to.attribute(minified, true).attribute(artifactType, "jar")
  79
  80         parameters {
  81             excludeFilesByArtifact = excludePatterns
  82         }
  83     }
  84
  85     implementation(libs.bouncycastle)
  86     implementation(libs.jackson.databind)
  87     implementation(libs.argparse4j)
  88     implementation(libs.dbusjava)
  89     implementation(libs.slf4j.api)
  90     implementation(libs.slf4j.jul)
  91     implementation(libs.logback)
  92     implementation(project(":libsignal-cli"))
  93 }
  94
  95 configurations {
  96     implementation {
  97         resolutionStrategy.failOnVersionConflict()
  98     }
  99 }
 100
 101
 102 tasks.withType<AbstractArchiveTask>().configureEach {
 103     isPreserveFileTimestamps = false
 104     isReproducibleFileOrder = true
 105 }
 106
 107 tasks.withType<JavaCompile> {
 108     options.encoding = "UTF-8"
 109 }
 110
 111 tasks.withType<Jar> {
 112     manifest {
 113         attributes(
 114             "Implementation-Title" to project.name,
 115             "Implementation-Version" to project.version,
 116             "Main-Class" to application.mainClass.get(),
 117             "Enable-Native-Access" to "ALL-UNNAMED",
 118         )
 119     }
 120 }
 121
 122 tasks.register("fatJar", type = Jar::class) {
 123     archiveBaseName.set("${project.name}-fat")
 124     exclude(
 125         "META-INF/*.SF",
 126         "META-INF/*.DSA",
 127         "META-INF/*.RSA",
 128         "META-INF/NOTICE*",
 129         "META-INF/LICENSE*",
 130         "META-INF/INDEX.LIST",
 131         "**/module-info.class",
 132     )
 133     duplicatesStrategy = DuplicatesStrategy.WARN
 134     doFirst {
 135         from(configurations.runtimeClasspath.get().map { if (it.isDirectory) it else zipTree(it) })
 136     }
 137     with(tasks.jar.get())
 138 }