nmode's Git Repositories - signal-cli/blob - lib/build.gradle.kts

   1 plugins {
   2     `java-library`
   3     `check-lib-versions`
   4 }
   5
   6 java {
   7     sourceCompatibility = JavaVersion.VERSION_17
   8     targetCompatibility = JavaVersion.VERSION_17
   9 }
  10
  11 val libsignalClientPath = project.findProperty("libsignal_client_path")?.toString()
  12
  13 dependencies {
  14     if (libsignalClientPath == null) {
  15         implementation(libs.signalservice)
  16     } else {
  17         implementation(libs.signalservice) {
  18             exclude(group = "org.signal", module = "libsignal-client")
  19         }
  20         implementation(files(libsignalClientPath))
  21     }
  22     implementation(libs.jackson.databind)
  23     implementation(libs.bouncycastle)
  24     implementation(libs.slf4j.api)
  25     implementation(libs.sqlite)
  26     implementation(libs.hikari)
  27
  28     testImplementation(libs.junit)
  29 }
  30
  31 tasks.named<Test>("test") {
  32     useJUnitPlatform()
  33 }
  34
  35 configurations {
  36     implementation {
  37         resolutionStrategy.failOnVersionConflict()
  38     }
  39 }
  40
  41 tasks.withType<AbstractArchiveTask>().configureEach {
  42     isPreserveFileTimestamps = false
  43     isReproducibleFileOrder = true
  44 }
  45
  46 tasks.withType<JavaCompile> {
  47     options.encoding = "UTF-8"
  48 }
  49
  50 tasks.jar {
  51     manifest {
  52         attributes("Automatic-Module-Name" to "org.asamk.signal.manager")
  53     }
  54 }